den4b Forum

const
  PdfInfoExe = 'pdfinfo.exe';
  Pattern = '[\n\r]Pages:\s+(\d+)\b';
  PadNumbersToLength = 6;

function ExtractPdfPageCount(const Path: WideString): Integer;
var
  Command: WideString;
  Output: String;
  Matches: TWideStringArray;
begin
  Result := 0;
  Output := '';
  Command := PdfInfoExe + ' "' + Path + '"';
  if ExecConsoleApp(UTF8Encode(Command), Output) = 0 then
  begin
    Matches := SubMatchesRegEx(UTF8Decode(Output), Pattern, False);
    if Length(Matches) > 0 then
      Result := StrToInt(Matches[0]);
  end;
end;

function PadZeros(const Number: Integer; MaxLength: Integer): String;
begin
  Result := IntToStr(Number);
  while Length(Result) < MaxLength do
    Result := '0' + Result;
end;

var
  Initialized: Boolean;
  TotalPageCount, PageCount: Integer;

begin
  if not Initialized then
  begin
    Initialized := True;
    TotalPageCount := 0;
  end;
  PageCount := ExtractPdfPageCount(FilePath);
  if PageCount > 0 then
  begin
    FileName :=
      PadZeros(TotalPageCount + 1, PadNumbersToLength) + '-' +
      PadZeros(TotalPageCount + PageCount, PadNumbersToLength) + ' ' +
      FileName;
    TotalPageCount := TotalPageCount + PageCount;
  end;
end.